/build/static/layout/Breadcrumb_cap_w.png

Casella Insight

Version: 199

Don't be a Stranger!

Sign up today to participate, stay informed, earn points and establish a reputation for yourself!

Sign up! or login
Views: 451  |  Created: 08/10/2018 by: VBScab

Average Rating: 0
Insight has 1 inventory records, 0 Questions, 0 Blogs and 0 links. Please help add to this by sharing more!

Deployment Tips (1)

Most Common Setup Type
Windows Installer (Delivered as an EXE)
Average Package Difficulty Rating
Rated 0 / 5 (Not Rated) based on 0 ratings
Most Commonly Reported Deployment Method
Not Determined
0
Note
The main installer for this app is an InstallShield EXE which can be driven by an ISS response file. However, the brain-dead packager at the 3rd-party used by this vendor omitted to silence the driver installation. When approached, Casella said, in essence, "Tough. We're too busy to bother with it." So, it fell to me to make it silent. Yes, I could have used AutoIt but there's no challenge in that!

Note that running the extracted MSI on its own fails to install the MySQL runtime or the scripts required to build the tables so forget that idea! Obviously, Mindteck found running it from a Custom Action too taxing.

During the installation:
- I copied the folder %TEMP%\{94991EC0-C537-47D4-A991-E9A1F3D96A1C} to a safe location, so that I had access to the EXEs, SQL scripts, etc. being used.
- I ran ProcMon so that I could capture the command lines being used.

Here's the resulting CMD. You can ignore entries for tools we use at the the client site (e.g. NOW). Hopefully, if you're reading this, you'll have the intelligence to map the EXE names mentioned with those that get extracted. If not, you should probably not be anywhere near work like this. Anyway...

SETLOCAL
set wrappername=Casella_Insight
set tools=C:\support\tools\0.Utils\
set logfile=C:\Support\logs\SCCM\%wrappername%_Wrapper.log
SET INSTALLOCATION=%~dp0
"%tools%now" -- Start of %wrappername% Install -- > %logfile%
:: The Casella tools write to this log file and expect it to be present.
set SQLLogFile=C:\Support\logs\SCCM\%wrappername%_MySQLSetup.log
"%tools%now" -- Create shell for MySQLSetup.LOG -- >> %SQLLogFile%
:Install_Drive
set exename=setup.exe
"%tools%now" -- Install %exename% -- >> %logfile%
"%INSTALLOCATION%app\Drive\%exename%" /S /NCRC
if NOT %errorlevel% == 0 goto :error
:Install_Insight
set msiname=Casella Insight.msi
"%tools%now" -- Install %msiname% -- >> %logfile%
msiexec.exe /i "%INSTALLOCATION%app\Insight\%msiname%" /qn ALLUSERS=1 REBOOT=ReallySuppress ROOTDRIVE=C:\ /lv "C:\Support\logs\SCCM\%wrappername%_%msiname%.log"
if %errorlevel% == 3010 goto :Install_Drivers
if NOT %errorlevel% == 0 goto :error
:Install_Driver_Ports
"%tools%now" -- Install 'Casella Ports' driver -- >> %logfile%
"%INSTALLOCATION%app\Insight\Drivers\dpinst" /c /q /lm /path "%INSTALLOCATION%app\Insight\Drivers\Casella Ports" /se /sw
if %errorlevel% == -2147418112 goto :Install_Driver_CDM
if %errorlevel% == -2147352576 goto :Install_Driver_CDM
if NOT %errorlevel% == 0 goto :error
:Install_Driver_CDM
"%tools%now" -- Install 'CDM' driver -- >> %logfile%
"%INSTALLOCATION%app\Insight\Drivers\dpinst" /c /q /lm /path "%INSTALLOCATION%app\Insight\Drivers\CDM" /se /sw
if %errorlevel% == -2147418112 goto :PluginRegistryStructureCreator_1
if %errorlevel% == -2147352576 goto :PluginRegistryStructureCreator_1
if NOT %errorlevel% == 0 goto :error
:PluginRegistryStructureCreator_1
"%tools%now" -- Run 'PluginRegistryStructureCreator.exe' with GUID {a221336b-bd36-3td9-b25e-6gcx33669355} -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {a221336b-bd36-3td9-b25e-6gcx33669355} 1 "%SQLLogFile%"
:Create_Registry_Entries
"%tools%now" -- Create registry entries -- >> %logfile%
reg add "HKLM\SOFTWARE\Casella Insight\Insight" /v MSQLC /d 1 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Insight" /v MSqlI /d 1 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Insight" /v InstallDirectory /d "C:\Program Files (x86)\Casella\Insight" /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Insight" /v UserName /d Cundall /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Insight" /v CompanyName /d Cundall /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Insight" /v PCode /d {a221336b-bd36-3td9-b25e-6gcx33669355} /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Insight" /v VersionInfo /d 199.005.15.00 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\APEX TUFF Plugin" /v PCode /d {cd537d30-1a8d-45aa-b9be-7c5a3251921d} /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\APEX TUFF Plugin" /v VersionInfo /d 199.006.08.00 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\CEL-35X Plugin" /v PCode /d {fec3c10a-e811-41c6-94b2-a257cadaebff} /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\CEL-35X Plugin" /v VersionInfo /d 199.008.09.00 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\CEL-62X Plugin" /v PCode /d {b720236a-aa49-4dc4-a67d-7db642773046} /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\CEL-62X Plugin" /v VersionInfo /d 199.007.07.00 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\CEL-63X Plugin" /v PCode /d {xyz9ps16-2mdk-50su-7vsw-6kqd99423o3r} /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\CEL-63X Plugin" /v VersionInfo /d 199.010.07.00 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\dBadge2 Plugin" /v PCode /d {mzgd26s3-k120-6f4u-260w-ad9hh69192b9} /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\dBadge2 Plugin" /v VersionInfo /d 199.017.03.00 /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\MicroDust Plugin" /v PCode /d {eaba02c2-a238-4a9e-840d-db5ee96087e3} /f /reg:32
reg add "HKLM\SOFTWARE\Casella Insight\Plugins\MicroDust Plugin" /v VersionInfo /d 199.009.09.00 /f /reg:32
:CreateBogusRegistryKeys
:: The wonderful developers at Mindteck India make their EXE crash 
:: with an exception error unless these keys are present...
"%tools%now" -- Create registry key 'HKLM\SOFTWARE\Mindteck India Limited\MySQLCasellaInsightInstaller\0.0.0.5' -- >> %logfile%
reg add "HKLM\SOFTWARE\Mindteck India Limited\MySQLCasellaInsightInstaller\0.0.0.5" /v EnableSystemEventsThreadAffinityCompatibility /t REG_DWORD /d 1 /f /reg:64
"%tools%now" -- Create registry key 'HKLM\SOFTWARE\Mindteck India Limited\DispMess\0.0.0.2' -- >> %logfile%
reg add "HKLM\SOFTWARE\Mindteck India Limited\DispMess\0.0.0.2" /v EnableSystemEventsThreadAffinityCompatibility /t REG_DWORD /d 1 /f /reg:64
:Stop_InsightService
"%tools%now" -- Stop MySQLCasellaInsight Service -- >> %logfile%
net stop MySQLCasellaInsight >> %logfile%
:Remove_InsightService
"%tools%now" -- Remove MySQLCasellaInsight Service -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\MySQLCasellaInsightServiceRemover.exe" "C:\ProgramData\Casella\Casella Insight\Database\MySQL\MySQL Server 5.1\bin\mysqld.exe" 1 "%SQLLogFile%"
:Copy_INS.BAT
:: Yet another triumph for Mindteck...
:: The installer MySQLCasellaInsightInstaller.exe checks for the 
:: presence of this file and throws an exception error if it's not present.
:: Its content is:
:: "%systemroot%\system32\net" stop MySQLCasellaInsight
:: "C:\ProgramData\Casella\Casella Insight\Database\MySQL\MySQL Server 5.1\bin\mysqld" --remove MySQLCasellaInsight --defaults-file="C:\ProgramData\Casella\Casella Insight\Database\my.ini"
:: "C:\ProgramData\Casella\Casella Insight\Database\MySQL\MySQL Server 5.1\bin\mysqld" --install MySQLCasellaInsight --defaults-file="C:\ProgramData\Casella\Casella Insight\Database\my.ini"
:: "%systemroot%\system32\net" start MySQLCasellaInsight
copy "%INSTALLOCATION%app\Insight\Setup\ins.bat" "%ProgramData%\Casella\Casella Insight\Installer" /Y
:Create_database
"C:\ProgramData\Casella\Casella Insight\Installer\MySQLCasellaInsightInstaller.exe" "-add" "%SQLLogFile%" "199.005.15.00"
:Kill_Processes
"%tools%now" -- Run KillProcesses.EXE -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\KillProcesses.exe" "%SQLLogFile%"
:Install_DotNetConnector
set msiname=mysql-connector-net-6.10.6.msi
"%tools%now" -- Install %msiname% -- >> %logfile%
msiexec.exe /i "%INSTALLOCATION%app\Dot Net Connector\%msiname%" /qn ALLUSERS=1 REBOOT=ReallySuppress ROOTDRIVE=C:\ /lv "C:\Support\logs\SCCM\%wrappername%_%msiname%.log"
if %errorlevel% == 3010 goto :Add_MySql.Data.dll_To_GAC
if NOT %errorlevel% == 0 goto :error
:Add_MySql.Data.dll_to_GAC
"%tools%now" -- Add 'MySql.Data.dll' to GAC -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\gacutil.exe" /i "C:\ProgramData\Casella\Casella Insight\Installer\MySql.Data.dll"
:Run_DBMainInstaller.EXE
"%tools%now" -- Run DBMainInstaller.EXE -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\CasellaDBMainInstaller.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaInsightNewDBTables.sql" 0 "%SQLLogFile%"
:Run_CreateProcUDF.EXE
"%tools%now" -- Run CreateProcUDF.EXE (executes 18 SQL scripts) -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaInsightNewDBProcedure1.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL62XNewDBTables.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL62XNewDBTableWithSP.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL35XNewDBTables.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL35XNewDBTableWithSP.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTablesMain.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables1.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables2.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables3.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables3_1.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables3_2.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables4.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaCEL63XNewDBTables5.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaApexTuffNewDBTables.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaApexTuffNewDBTableWithSP.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CasellaMicroDustNewDBTables.sql" "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\CreateProcUDF.exe" "%INSTALLOCATION%app\Insight\Setup\CaselladBadge2NewDBTables.sql" "%SQLLogFile%"
:Add_ilist.txt_To_GAC
"%tools%now" -- Add 'ilist.txt' content to GAC -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\gacutil.exe" /il "%INSTALLOCATION%app\Insight\Setup\ilist.txt"
:Run_InsightRegistration.EXE
"%tools%now" -- Run 'InsightRegistration.EXE' -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\InsightRegistration.exe" {a221336b-bd36-3td9-b25e-6gcx33669355} "%SQLLogFile%"
:Run_InsightServiceInstaller.EXE
"%tools%now" -- Run 'InsightServiceInstaller.EXE' against 'C:\WINDOWS\SysWOW64\klpnm.exe' -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\InsightServiceInstaller.exe" /i "C:\WINDOWS\SysWOW64\klpnm.exe" "%SQLLogFile%"
:Start_InsightServiceInstaller
"%tools%now" -- Start 'InsightServiceInstaller -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\InsightServiceInstaller.exe" start instdt "%SQLLogFile%"
:StartInsightService
"%tools%now" -- Start MySQL Service -- >> %logfile%
net start MySQLCasellaInsight >> %logfile%
:PluginRegistryStructureCreator_2
"%tools%now" -- Run 'PluginRegistryStructureCreator.exe' -- >> %logfile%
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {a221336b-bd36-3td9-b25e-6gcx33669355} 1 "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {b720236a-aa49-4dc4-a67d-7db642773046} 1 "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {fec3c10a-e811-41c6-94b2-a257cadaebff} 1 "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {xyz9ps16-2mdk-50su-7vsw-6kqd99423o3r} 1 "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {cd537d30-1a8d-45aa-b9be-7c5a3251921d} 1 "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {eaba02c2-a238-4a9e-840d-db5ee96087e3} 1 "%SQLLogFile%"
"%INSTALLOCATION%app\Insight\Setup\PluginRegistryStructureCreator.exe" {mzgd26s3-k120-6f4u-260w-ad9hh69192b9} 1 "%SQLLogFile%"
:AddToPath
"%tools%now" -- Add MySQL folder to System PATH -- >> %logfile%
SETX PATH "%PATH%;C:\ProgramData\Casella\Casella Insight\Database\MySQL\MySQL Server 5.1\bin;" /M
:SetPermissions_C_ProgramFiles(x86)_Casella_Insight
"%tools%now" -- Set Permissions on 'C:\Program Files (x86)\Casella\Insight' -- >> %logfile%
"%tools%x86\setacl.exe" -on "C:\Program Files (x86)\Casella\Insight" -ot file -actn ace -ace "n:Users;p:change;m:grant" -log "C:\Support\logs\SCCM\%wrappername%_C_ProgramFiles(x86)_Casella_Insight.log"
if NOT %errorlevel% == 0 goto :error
:SetPermissions_C_ProgramData_Casella_Casella_Insight
"%tools%now" -- Set Permissions on 'C:\ProgramData\Casella\Casella Insight' -- >> %logfile%
"%tools%x86\setacl.exe" -on "C:\ProgramData\Casella\Casella Insight" -ot file -actn ace -ace "n:Users;p:change;m:grant" -log "C:\Support\logs\SCCM\%wrappername%_C_ProgramData_Casella_Casella_Insight.log"
if NOT %errorlevel% == 0 goto :error
:Cleanup
del "C:\Users\Public\Desktop\Casella Insight.lnk" /F /Q
del "C:\Users\Public\Desktop\CasellaDrive.lnk" /F /Q
del "C:\Users\Public\Desktop\Optimize Insight Database.lnk" /F /Q
goto :end
:error
"%tools%now" -- Error in %wrappername% Install -- >> %logfile%
exit 1
:end
"%tools%now" -- End of %wrappername% Install -- >> %logfile%
exit 0

Setup Information:
Setup Type: Windows Installer (Delivered as an EXE)
Deployment Method Used: unspecified
Deployment Difficulty: unspecified
Platform(s): Windows

Inventory Records (1)

View inventory records anonymously contributed by opt-in users of the K1000 Systems Management Appliance.

Insight

Version

199.005.15.00

Questions & Answers (0)

Questions & Answers related to Casella Insight

Blogs (0)

Blog posts related to Casella Insight

Reviews (0)

Reviews related to Casella Insight