Hawkes Learning Systems Statistics

Version: 9
Views: 706  |  Created: 11/18/2010

Average Rating: 0
Statistics has 1 inventory records, 0 Questions, 0 Blogs and 0 links. Please help add to this by sharing more!

Deployment Tips (1)

Most Common Setup Type
Windows Installer (Delivered as an EXE)
Average Package Difficulty Rating
Rated 5 / 5 (Very Difficult) based on 1 ratings
Most Commonly Reported Deployment Method
Vendor Provided Command Line (switch driven)
or cancel
0
Note

Version:  9.7


This was by far one of the most annoying installs I've had to work with.  There are flags for installation/uninstallation but no information can be found from Hawkes' own online resources nor could I find the flags with normal means such as extracting the EXE or looking for /? or /help information.  I did note an MSI inside the EXE for Statistics 9.7, the version I was working with, so I attempted to use the \qn flag and, thankfully, it worked.  My script works by installing Statistics and then uninstalling the Update Manager program.

NOTE:  If you don't already have Flash Player 11+ installed on the machine then it will install Flash Player 11.  My uninstall script, below, does not remove this so you will want to find and remove it yourself if you so desire.

install_statistics.cmd

:: Turn echo off and clear command prompt window.
@echo off
cls

:: set program=Program Name
set "program=Hawkes Learning Systems Statistics"

:: set installer=%~dp0somefile.ext
set installer=%~dp0statbeg-student-setup.exe
set updaterPath=%programdata%\{2CB7E68C-946F-4273-97CC-85B3F2AB1353}
set "updaterProg=Hawkes Update Service Manager.exe"

echo Installing %program% - Please Wait
echo Started @ %time%
echo Window will close once complete.
echo.
echo.

:: Check which OS arch-type is being used
if exist "%programfiles(x86)%" (goto x64) else (goto x86)

:x64
	:: Check if program exists or not
	if exist "%programfiles(x86)%\Hawkes Learning Systems\Statistics\HLSTOC.exe" (
		echo %program% found.  Exiting.
		set EXIT_CODE=1337
		goto end
	)
	
	goto install

:x86
	:: Check if program exists or not
	if exist "%programfiles%\Hawkes Learning Systems\Statistics\HLSTOC.exe" (
		echo %program% found.  Exiting.
		set EXIT_CODE=1337
		goto end
	)
	
	goto install

:install
	:: Install program
	echo %program% not installed.  Installing.
	start /wait "%program% Installing" "%installer%" /qn
	
	:: Remove updater program
	echo.
	echo Uninstalling the Updater program.
	start /wait "Uninstalling Updater" "%updaterPath%\%updaterProg%" /qn REMOVE=TRUE MODIFY=FALSE
	
	:: Remove folders if they exist
	echo.
	echo Removing left-over directories.
	if exist "%programfiles(x86)%\Hawkes Learning Systems\Hawkes Update Service Manager" rmdir "%programfiles(x86)%\Hawkes Learning Systems\Hawkes Update Service Manager" /s /q
	if exist "%programfiles%\Hawkes Learning Systems\Hawkes Update Service Manager" rmdir "%programfiles%\Hawkes Learning Systems\Hawkes Update Service Manager" /s /q
	if exist "%programdata%\~0" rmdir "%programdata%\~0" /s /q
	
	goto end

:end
	:: Finish time
	echo.
	echo Finished @ %time%

	:: Return exit code to SCCM
	exit /B %EXIT_CODE%

uninstall_statistics.cmd

:: Turn echo off and clear command prompt window.
@echo off
cls

:: set program=Program Name
set "program=Hawkes Learning Systems Statistics"

:: set uninstaller=program.ext
:: use %~dp0 if uninstaller is in directory with script
set "statsPath=%programdata%\{57CFA262-ED82-4C61-A9C3-07617B420668}"
set "statsProg=statbeg-student-setup.exe"
set "updaterPath=%programdata%\{2CB7E68C-946F-4273-97CC-85B3F2AB1353}"
set "updaterProg=Hawkes Update Service Manager.exe"

echo Uninstalling %program% - Please Wait
echo Started @ %time%
echo Window will close once complete.
echo.
echo.

:: Check which OS arch-type is being used
if exist "%programfiles(x86)%" (goto x64) else (goto x86)

:x64
	:: Check if program exists or not
	if exist "%programfiles(x86)%\Hawkes Learning Systems\Statistics\HLSTOC.exe" (
		goto uninstall
	)
	
	echo %program% not found.  Exiting.
	set EXIT_CODE=1337
	goto end

:x86
	:: Check if program exists or not
	if exist "%programfiles%\Hawkes Learning Systems\Statistics\HLSTOC.exe" (
		goto uninstall
	)
	
	echo %program% not found.  Exiting.
	set EXIT_CODE=1337
	goto end
	
:uninstall
	:: Uninstall program
	echo %program% found. Uninstalling.
	start /wait "%program% Uninstalling" "%statsPath%\%statsProg%" /qn REMOVE=TRUE MODIFY=FALSE
	
	if exist "%updaterPath%\%updaterProg%" (
		:: Remove updater program
		echo.
		echo Uninstalling the Updater program.
		start /wait "Uninstalling Updater" "%updaterPath%\%updaterProg%" /qn REMOVE=TRUE MODIFY=FALSE
	)	
	
	:: Remove folders if they exist
	echo.
	echo Removing left-over directories if they exist.
	if exist "%programdata%\~0" rmdir "%programdata%\~0" /s /q
	if exist "%programdata%\~1" rmdir "%programdata%\~1" /s /q
	
	:: Will need to remove the Hawkes folder from the Program Files folder individually after
	:: a reboot as there are files in the Common dirctory there that prevent deletion until
	:: the computer is restarted.  They do delete themselves after reboot.
	
	goto end

:end
	:: Finish time
	echo.
	echo Finished @ %time%

	:: Return exit code to SCCM
	exit /B %EXIT_CODE%
Setup Information:
Setup Type: Windows Installer (Delivered as an EXE)
Deployment Method Used: Vendor Provided Command Line (switch driven)
Deployment Difficulty: Very Difficult
Platform(s): Windows
Please log in to comment

Inventory Records (1)

View inventory records anonymously contributed by opt-in users of the K1000 Systems Management Appliance.

Versions

Statistics

Version

9.5.0

Uninstall String

C:\ProgramData\{34FBD9E2-57BE-40C8-B2FF-77D28CB5D17A}\STATBEG-Student-Setup.exe C:\ProgramData\{F3B7C7A8-D1AA-4B44-84FA-5B63DB34565D}\STATDIS-Student-Setup.exe

Questions & Answers (0)

Questions & Answers related to Hawkes Learning Systems Statistics

Blogs (0)

Blog posts related to Hawkes Learning Systems Statistics

Reviews (0)

Reviews related to Hawkes Learning Systems Statistics