Software Deployment

Got a sample of your code handy? It's hard to guess with nothing to go on. I've used VB to successfully create shortcuts in all users desktop. If you are using VB let me know.

Unfortunately I'm not using VB. Never been good at it.

so what are you using?

Simple batch file.

copy "P:\apps\XXX\XXX.exe" "c:\document and settings\all users\desktop"

the "XXX.exe" is the shortcut.

should be
c:\documents and settings\all users\desktop

You are right.. I mistyped. It was Documents and Settings

1, An EXE isn't a shortcut
2, Who on earth decided that the Desktop was a good place to put shortcuts? What is the Start menu for, if not for shortcuts?

1. With Best Case (the program I am using), winbfs.exe is the file needed to access the network app. (the properties point to the network location)

2. my company wants this particular short cut on the desktop

I know the usual shortcut is a .lnk or .ico. This not the case here.

I need to create a short cut which points to the start up.exe. silently. (deployed using SCCM) for a large numbers of pcs.

i have created a shortcut using below command line:

I'm not using VB. Never been good at it.There's a post which has been active today which has ready-rolled code for you. All you need to do is edit the details.

At the risk of being b-slapped for stupid questions, let me ask, where can I locate this info?

I think I've posted on this message board twice and I'm not sure of where info is.

Try adding this VB script if you want a shortcut on your All Users Desktop. You will need to modify it to point to your startup.exe. This creates a shortcut and doesn't just copy one. You'll need an icon for it as well.

'
' Create a shortcut to C:\Windows\System32\Notepad.exe on the All Users Desktop
'
Const ALL_USERS_DESKTOP = &H19&
Const SYSTEM = &H25&
Const strNotepadExe = "Notepad.exe"
Dim objFSO, objShell, objFolder, objFolderItem, WshShell, objLink
Dim strWindowsDir
Dim strSystemPath, strAllUsersDesktopPath
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Shell.Application")
Set WshShell = CreateObject("WScript.Shell")
Set objFolder = objShell.Namespace(SYSTEM)
Set objFolderItem = objFolder.Self
strSystemPath = objFolderItem.Path
Set objFolder = objShell.Namespace(ALL_USERS_DESKTOP)
Set objFolderItem = objFolder.Self
strAllUsersDesktopPath = objFolderItem.Path
strAllUsersDesktopPathIcons = "C:\My_Icons"

'
' If My_Shortcut_to_Notepad shortcut is missing from the strAllUsersDesktopPath folder, recreate it
'
If Not (objFSO.FileExists(strAllUsersDesktopPath & "\My_Shortcut_to_Notepad.lnk")) Then
Call CreateShortcut
End If
WScript.Quit
Sub CreateShortcut
Set objLink = WshShell.CreateShortcut(strAllUsersDesktopPath & "\My_Shortcut_to_Notepad.lnk")
objLink.Description = "This is the description of My Shortcut"
objLink.IconLocation = strAllUsersDesktopPathIcons & "\MyIcon.ico"
objLink.TargetPath = strSystemPath & "\" & strNotepadExe
objLink.WindowStyle = 3
objLink.WorkingDirectory = strSystemPath
objLink.Save
End Sub

I wanted to thank you. This script did exactly what I needed. Appreciated the help.