someone help me how disable internet explorer  compatibility view settings vai sccm batch file or VB script

0 Comments   [ + ] Show Comments

Comments

Please log in to comment

Answers

2

which version of IE? be more specific with your question (we wish we had crystal balls you know!)

if you are going to tweak IE settings I highly recommend your first stop to Microsoft's IE Admin Kit site: http://technet.microsoft.com/en-gb/ie/bb219517.aspx

There you can manage and customise your IE setups including the compatiblity view setting.

Alternatively, here is the code for a batch file which edits the registry keys:

@ECHO off
SETLOCAL
 
:: let's get the IE version first
SET qry=REG QUERY "HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer" /v Version
SET fnd=FINDSTR /I /L /C:"REG_SZ"
FOR /f "Tokens=2*" %%u IN ('%qry%^|%fnd%') DO ( SET IEVerReg=%%v )
FOR /f "Tokens=1,2,3,4 Delims=." %%a IN ("%IEVerReg%") DO ( SET IEVerMaj=%%a&SET IEVerMin=%%b&SET IEVerBld=%%c&SET IEVerRev=%%d )
 
IF %IEVerMaj% EQU 9 IF %IEVerMin% GEQ 10 SET IEVerMaj=10
SET /a REG_VALUE=IEVerMaj*1000
 
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION" /v "iexplore.exe" /t REG_DWORD /d %REG_VALUE% /f
REG ADD "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION" /v "iexplore.exe" /t REG_DWORD /d %REG_VALUE% /f
:: 64bit Users
IF %PROCESSOR_ARCHITECTURE%==AMD64 (
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION" /v "iexplore.exe" /t REG_DWORD /d %REG_VALUE% /f
REG ADD "HKEY_CURRENT_USER\SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION" /v "iexplore.exe" /t REG_DWORD /d %REG_VALUE% /f
)
 
ENDLOCAL

 

Answered 08/23/2013 by: mattski
Second Degree Green Belt

Please log in to comment
Answer this question or Comment on this question for clarity