Software Deployment

'KACE IE10 Uninstall Script
'Joe Ostrander

'Requirements:

'	1) Custom Software Inventory item for IE10 
'		a) using rule:  FileInfoEquals(c:\Program Files\Internet Explorer\iexplore.exe, FileMajorPart, NUMBER, 10)
'		b) Attach this script as the Associated File
'	2) Managed Install for the custom app
'		a) Installation Command
'			i) Configure Manually
'			ii) command = wscript.exe Uninstall_IE10.vbs
'			iii) check to enable "Un-Install using Full Command Line"
'		b) Managed action = Execute anytime
'		c) Select your deployment options (All machines... custom label... etc)

ON ERROR RESUME NEXT

Set RegEx = New RegExp
RegEx.Pattern = "Microsoft-Windows-InternetExplorer-(.*?)10\.(.*?)\.mum"
RegEx.IgnoreCase = True

Set fso = CreateObject("Scripting.FileSystemObject")
Set WshShell = CreateObject("WScript.Shell")

If fso.FileExists("c:\windows\sysnative\wscript.exe") Then
	'if 32 on 64...relaunch (KACE agent runs as 32bit... this script should run as 64bit)
	WshShell.run "c:\windows\sysnative\wscript.exe //nologo " & Chr(34) & wscript.scriptfullname & Chr(34),,True
	Wscript.quit
End If

Set oFolder = fso.GetFolder("C:\Windows\Servicing\Packages")
For Each oFile in oFolder.Files
	If RegEx.Test(oFile.Name) Then
		WshShell.Run "pkgmgr /up:""" & fso.GetBaseName(oFile) & """ /quiet /norestart",0,True
	End If
Next

I have version 10 on my station and it looks like you can reference the registry key svcversion for version 10

This is the release version info.  We are using

RegistryValueGreaterThan(HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer, svcVersion, 10.0)

but after it is full release then svcVersion will not work and then you would have to use just Version key.