1. Download installer
https://signup.oce.leagueoflegends.com/en/signup/index#/
2. Deploy software with a batch script
Obtain fsync.exe - http://www.vicosoft.it/en/fsync.html
NB - This script was initially created in Silent Batch Maker, a very useful tool to help create silent installers quickly - https://github.com/nsy16/SilentBatchMaker/releases
install.cmd
@echo off&cls
for %%a in ("%~dp0\.") do set _parentdir=%%~nxa
title %_parentdir%
:: Install LoL
set _fPath=%~dp0League of Legends installer OC1.exe
set _swtch=--unattendedmodeui minimal --mode unattended --license_agreement 1
set _regKy=League of Legends 1.0
set _regDN=League of Legends
set _regDV=1.0
:: query registry for DisplayVersion 64bit and 32bit uninstall locations
for /f "tokens=3" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\%_regKy%" /v "DisplayVersion" 2^>nul') do if "%%a" geq "%_regDV%" goto :end
for /f "tokens=3" %%a in ('reg query "HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\%_regKy%" /v "DisplayVersion" 2^>nul') do if "%%a" geq "%_regDV%" goto :end
:: install software
echo Installing %_regDN% %_regDV%
start /wait "" "%_fPath%" %_swtch%
:: overwrite folder with 'good' version
echo Updating cache files 1400+...
if not exist "%temp%\fsync.exe" copy "%~dp0fsync.exe" "%temp%" >nul
"%temp%\fsync.exe" "%~dp0RADS" "C:\Riot Games\League of Legends\RADS" /k /f
:end
:: cleanup
del "C:\Users\Public\Desktop\League of Legends.lnk" 2>nul
del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\League of Legends\Uninstall League of Legends.lnk" 2>nul
3. Update local cache
Launch game and ensure it is updated
Use the following script to update your local installer cache
@echo off&cls
for %%a in ("%~dp0\.") do set _parentdir=%%~nxa
title %_parentdir%
:: Update Cache LoL
:: cleanup
del "C:\Users\Public\Desktop\League of Legends.lnk" 2>nul
del "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\League of Legends\Uninstall League of Legends.lnk" 2>nul
:: overwrite folder with 'good' version
echo Updating cache files 1400+...
if not exist "%temp%\fsync.exe" copy "%~dp0fsync.exe" "%temp%" >nul
"%temp%\fsync.exe" "C:\Riot Games\League of Legends\RADS" "%~dp0RADS" /k /f
:end
pause
View inventory records anonymously contributed by opt-in users of the K1000 Systems Management Appliance.