I had a heck of a time finding trying to find this info so I figured I'd put it here in case anyone else has the same trouble. These instructions should work on most Officejet models, although I've only tested it personally on the HP Officejet 6600 and the HP Officejet Pro 8600 models.

We are deploying about 150 HP Officejet Pro 8600 All-in-one printers to our sales force so I was tasked with deploying the HP software to their laptops with no user interaction. They all have Windows 7 Professional 64-bit laptops so my instructions here will be for that particular system, although the link provided below has instructions for other systems as well.

I found some great information on HP's site for an "Enterprise Install" for 8500A and 8600 models, but as I said it should work for other models as well. They have the instructions here:

http://h30434.www3.hp.com/psg/attachments/psg/Install/56628/1/Enterprise%20Install%20for%20HP%20Officejet%20Pro%208500A%20and%208600%20Printers.pdf

First of all, I downloaded the full install package from HP's support site which was located here:

http://ftp.hp.com/pub/softlib/software12/COL40120/mp-97846-2/OJ8600_619.exe

Next, using 7-Zip I extracted the files contained in the above .exe file to a folder on the C: drive. Now, as many of you know, HP is known for including a lot of extra "stuff" in their installers that most of us don't want. Luckily, they have provided us with a way to slim down the size of the install package. Using this method, I was able to shrink the original install file, which was 119 MB initially, down to about 75 MB, and then zipped the package down to around 38 MB which of course is a lot more manageable to deploy. To do the slim down, I created a batch file with the following contents. This script can be found in the pdf I linked to above on page 10 - Appendix A:

@echo off
echo Creating Enterprise Release
echo This will delete files in the current directory to create the release.
echo Press Ctrl+C now if this is not what you want to do
pause
SET /P FAX="Include FAX? [Y|N] "
SET /P PLATFORM="32 bit, 64 bit, or Both? [32|64|Both] "
SET /P LANGUAGE="Specify Language ID or All? [{LanguageID}|All] "
rmdir /Q /S Optional
rmdir /Q /S HP
rmdir /Q /S Microsoft
rmdir /Q /S Toolbar
rmdir /Q /S Required
rmdir /Q /S licensing
del /F /Q Full_*.cab
del /F Setup.exe
del /F HP-DQEX5.exe
del /F autorun.inf
del /F ReadMe.chm
if "%FAX%"=="N" (
pushd Drivers
rmdir /Q /S Fax
popd
del /F /Q HP*_fax.inf
del /F /Q HP*_fax*.cat
) ELSE (
REM The nullfax driver might be inside of the MSI in K3.5/K4, but we'll try to remove it anyway
del /F /Q HP*_nullfax*.inf
del /F /Q HP*_nullfax*.cat
)
if "%PLATFORM%"=="32" (
del /F /Q *x64.msi
del /F /Q *x64.cab
del /F /Q *x64_*.mst
)
if "%PLATFORM%"=="64" (
del /F /Q *x86.msi
del /F /Q *x86.cab
del /F /Q *x86_*.mst
)
if "%LANGUAGE%"=="All" GOTO :SKIP_LANGUAGES
FOR %%F in (*%LANGUAGE%*.mst) DO ren "%%F" "%%~nF._mst"
del /F /Q *.mst
FOR %%F in (*._mst) DO ren "%%F" "%%~nF.mst"
:SKIP_LANGUAGES
echo All Done!

This batch file needs to be run from the same directory as the extracted install files. When I ran the file, I chose the following options, although your choices may be different depending on your needs:

Include Fax = Y 32 bit, 64 bit or both = 64 Specify Language ID or All = 1033

To deploy the zip file, I created a File Synchronization entry to copy the zip file to the laptops. Since the File Synchronization section does not always unzip things as expected, I then created a script to unzip the files. Finally, once the files were unzipped, I used another script to run the install, which again I based on the info in the PDF mentioned above. Here is the command line I used:

@echo off

CLS
title Installing HP OfficeJet 8600 Software - Please Do Not Close...

msiexec /i C:\Utilities\HP_OJ_8600\OJ860x64.msi /qn /l*v C:\HP_8600_Install.log ENTERPRISE=NO FAX=YES IGNORE_SERIALNUM=YES REBOOT=ReallySuppress

Once the software is installed, all the user has to do is power on the printer then plug the USB cable in. They will see the plug and play icon show up momentarily in the system tray then it will go away. You should then see the printer show up in the Devices and Printers section.

All of our sales people have "Standard User" rights on their machines. Installing it this way eliminates the need for an Admin to enter credentials to finish the install.