@ECHO OFF
TITLE CodeLink Standalone Install
CLS

ECHO.
ECHO     Adding Deployment Data for the Registry
ECHO     =======================================
Set CompanyName=Context4 Healthcare
Set DisplayName=CodeLink
Set DisplayVersionAPP=2.1.1.6
Set DisplayVersionDB=2.0.1.13
Set DisplayVersionUpd=2.1.1.3
Set KeyLocation="HKEY_LOCAL_MACHINE\Software\UKHC IT\SupportedPackages\%CompanyName%\%DisplayName%"
reg add %KeyLocation% /f >NUL
reg add %KeyLocation% /v DisplayVersionAPP /t REG_SZ /d "%DisplayVersionAPP%" /f >NUL
reg add %KeyLocation% /v DisplayVersionDB /t REG_SZ /d "%DisplayVersionDB%" /f >NUL
reg add %KeyLocation% /v DisplayVersionUPD /t REG_SZ /d "%DisplayVersionUpd%" /f >NUL
reg add %KeyLocation% /v InstallType /t REG_SZ /d "SCCM" /f >NUL
reg add %KeyLocation% /v InstallBegin /t REG_SZ /d "%DATE:~4% %time:~0,-3%" /f >NUL

ECHO.
ECHO     Installing Applications: %time:~0,-6%
ECHO     ==============================
ECHO      + CodeLink SQL App
msiexec /i "%~dp0CodeLinkSQLApp.msi" AgreeToLicense=YES ALLUSERS=1 /q
SET AppEL2=%errorlevel%
reg add %KeyLocation% /v SQLAppExitLvl /t REG_SZ /d "%AppEL2%" /f >NUL

ECHO      + CodeLink SQL DB
msiexec /i "%~dp0CodeLinkSQLDB.msi" AgreeToLicense=YES ALLUSERS=1 /qn
SET AppEL1=%errorlevel%
reg add %KeyLocation% /v SQLDBExitLvl /t REG_SZ /d "%AppEL1%" /f >NUL

ECHO      + CodeLink Updater
msiexec /i "%~dp0CodeLinkUpdater.msi" AgreeToLicense=YES ALLUSERS=1 /qn
SET AppEL3=%errorlevel%
reg add %KeyLocation% /v SQLUpdaterExitLvl /t REG_SZ /d "%AppEL3%" /f >NUL
ECHO      = Complete

ECHO.
ECHO     Setting Folder Permissions: %time:~0,-6%
ECHO     =================================
IF EXIST "C:\Program Files (x86)" (
  icacls "C:\Program Files (x86)\Context4 Healthcare\CodeLink" /GRANT "Interactive:(OI)(CI)F"
) ELSE (
  icacls "C:\Program Files\Context4 Healthcare\CodeLink" /GRANT "Interactive:(OI)(CI)F"
)

reg add %KeyLocation% /v InstallEnd /t REG_SZ /d "%DATE:~4% %time:~0,-3%" /f >NUL