I am trying to figure out how to add Adobe Flash player to client windows PCs.  I have downloaded the flash installer .exe.  When I go to distribution/choose action/Add New Item, it doesn't seem to be the correct place to do it.

Thanks,

Chris

 

0 Comments   [ + ] Show Comments

Comments

Please log in to comment

Community Chosen Answer

1

you are in the right place, go to Distribution, managed Installation, add new item

if the version does not exist you need to create a software label for that software and choose that one.  upload the install and add the proper run switches you want under run parameters

 

Answered 12/26/2012 by: SMal.tmcc
Red Belt

Please log in to comment

Answers

0

I use a batch file for my flash installs, so the old version(s) get scrubbed and the install goes through successfully the first time. In the actual managed install, I have Installation Command set to "Configure Manually" and enter the name of the batch file (which I zip up along with the flash installer and the two flash uninstallers referenced in the batch file below, downloadable from Adobe's site).  You'll notice at the end that the x86 and x64 sections use the same installer - previously there were separate ones, so I've left this intact in case they decide to ever make that distinction again.

Hope that helps!

John

_______________________________

Here's the batch file:

:: flash player uninstaller & updater
::
:: kills any programs that might be using flash player
:: checks for bitness (x86 or x64)
:: runs appropriate version of flash player uninstaller
:: cleans up folders
:: checks again for OS bitness (x86 or x64)
:: installs appropriate version of latest flash player
::
:: you can also use this to uninstall newer versions (i.e. 11)
:: and then install earlier versions (i.e. 10)
:: just change the installer used at the bottom

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Kill any programs that might be using flash player
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::

taskkill /F /IM iexplorer.exe
taskkill /F /IM iexplore.exe
taskkill /F /IM firefox.exe
taskkill /F /IM chrome.exe

:: Just for shorten and avoid errors, creating a env for command
set tl=tasklist /nh /fo csv /m
:: Terminate all ActiveX consumers...
FOR /F "delims=, tokens=1,2,3*" %%a IN ('%tl% flash*') DO taskkill /f /im %%a 2> nul
:: Terminate all Plug-in consumers..
FOR /F "delims=, tokens=1,2,3*" %%a IN ('%tl% npsw*') DO taskkill /f /im %%a 2> nul

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: OS bitness check and flash player uninstall
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::

if /i %processor_architecture%==x86 GOTO x86

:: Remove flash player (64-bit)
uninstall_flash_player_64bit.exe -uninstall

:x86
:: Remove flash player (32-bit)
uninstall_flash_player_32bit.exe -uninstall

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Cleanup all related flash player folders
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::

del "C:\Windows\system32\Macromed\Flash\*" /Q /F /S
for /d %%X in ("C:\Windows\system32\Macromed\Flash\*") do RMDIR /S /Q %%X
del "%appdata%\Adobe\Flash Player\*" /Q /F /S
for /d %%X in ("%appdata%\Adobe\Flash Player\*") do RMDIR /S /Q %%X
del "%appdata%\Macromedia\Flash Player\*" /Q /F /S
for /d %%X in ("%appdata%\Macromedia\Flash Player\*") do RMDIR /S /Q %%X

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: OS bitness check and MI check-in
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::

if /i %processor_architecture%==AMD64 GOTO x64
if /i %processor_architecture%==x86 GOTO x86

:x64
:: install adobe flash player (64-bit)
msiexec.exe /i install_flash_player_11_active_x.msi /qn
GOTO END

:x86
:: install adobe flash player (32-bit)
msiexec.exe /i install_flash_player_11_active_x.msi /qn

:END
Answered 12/28/2012 by: jverbosk
Red Belt

Please log in to comment
Answer this question or Comment on this question for clarity