Software

You can create a verbose log file during the install. All properties are listed at the bottom of it.

googled this

http://scriptbox.toll.at/index.php?showcontent=Get%20MSI-File%20properties.vbs&list=1

http://serverfault.com/questions/384904/retrieving-public-properties-from-an-msi-file

Hi,
get hold of Orca, or if your a Dell customer RayPack For Dell KACE. You can then open the MSI file and examine the Properties in the Property table.

Cheers
Phil

Since public properties don't contain lower case characters, you'd probably want something like this to automate it:

Const msiOpenDatabaseModeReadOnly = 0
Const msiOpenDatabaseModeTransact = 1

'create WindowsInstaller.Installer object
Dim oInstaller : Set oInstaller = CreateObject("WindowsInstaller.Installer")
 
'open the MSI (the first argument supplied to the vbscript)
Dim oDatabase : Set oDatabase = oInstaller.OpenDatabase(WScript.Arguments(0),msiOpenDatabaseModeReadOnly)
 
'create a view of the registry we want to see
Dim sql : sql = "SELECT `Property`,`Value` FROM `Property`"
Dim propView : Set propView = oDatabase.OpenView(sql)
 
'execute the query
propView.Execute
 
'fetch the first row of data (if there is one!)
Dim propRecord : Set propRecord = propView.Fetch
 
'whilst we've returned a row and therefore propRecord is not Nothing
While Not propRecord Is Nothing
 
    if (StrComp(propRecord.StringData(1),UCase(propRecord.StringData(1))) = 0) Then       
        wscript.echo "Property Name: " & propRecord.StringData(1) & vbCrlf & "Property Value: " & propRecord.StringData(2)
    End If

'go and fetch the next row of data
Set propRecord = propView.Fetch
Wend
 
propView.Close
Set propView = Nothing
Set propRecord = Nothing
Set oDatabase = Nothing
Set oInstaller = Nothing


(Script takes the MSI as the first argument). See here for more info on scripting with Windows Installer.  Also bear in mind that you may not want to omit some restricted properties and/or some standard public properties.